Sub 바이패스키_비활성화()

On Error GoTo HError

'바이패스 키를 비활성화 시키는 프로시저
'주의: 이 명령을 한 번 실행하면 되돌릴 수 없습니다.
'반드시 백업 후 이 명령을 실행시키십시오.
'작성자: 염기웅: carl@td21.com

    Dim objProperty As Object
    
    CurrentDb.Properties("AllowBypassKey") = False
    MsgBox "바이패스키를 비활성화 했습니다."
    Exit Sub

HError:
    Select Case Err.Number
        Case 3270   '속성이 없을 경우: 새로 만든다.
            CurrentDb.Properties.Append CurrentDb.CreateProperty("AllowBypassKey", dbBoolean, False)
            Resume Next
        Case Else
            MsgBox "바이패스키를 비활성화할 수 없습니다." & vbNewLine & _
                   Err.Description & vbNewLine & _
                   Err.Number
    End Select

End Sub

Public Sub 바이패스키_비활성화_ADP()

'바이패스 키를 비활성화 시키는 프로시저 (ADP 전용)
'주의: 이 명령을 한 번 실행하면 되돌릴 수 없습니다.
'반드시 백업 후 이 명령을 실행시키십시오.
'작성자: 염기웅: carl@td21.com

On Error GoTo Herror

    CurrentProject.Properties("AllowBypassKey").Value = False
	MsgBox "바이패스키를 비활성화 했습니다."
    Exit Sub
    
Herror:
    Select Case Err.Number
        Case 2455   'AllowBypassKey 속성이 없을 경우: 'AllowBypassKey' 속성에 유효하지 않은 참조를 사용하는 식을 입력했습니다.
            CurrentProject.Properties.Add "AllowBypassKey", False
            Resume
        
        Case Else
            MsgBox "바이패스키를 비활성화할 수 없습니다." & vbNewLine & _
                   Err.Description & vbNewLine & _
                   Err.Number
            
    End Select
    
End Sub